OSDev.org

Code: Select all

; This structure is an example

Structure:
DATA_1   DW 1
DATA_2   DW 5
Length    DW 7
DATA_3   DB  2


; Here the code

                xor ax,ax                                  ; AX = 0
                mov cx,[Length]                        ; Load Structure Length
                mov si, OFFSET Structure           ; SI = Offset Structure
Checksum:
                add   al, [si]
                add   si,1
                sub   cx,1
                jnz    Checksum
 
                test  al,al                                ; IF AL = 0 , STRUCTURE IS VALID
                jz     CHECKSUM_SUCCESS

                

Code: Select all

%ifndef __X86LIB_RMVIDEO__
%define __X86LIB_RMVIDEO__

    ;===========================================================================
    ; Description: Prints a null-terminated string to the screen.
    ;---------------------------------------------------------------------------
    ; Parameters:-
    ;     DS:SI - The segment:offset of the null-terminated string.
    ;     BL    - The foreground colour.
    ;     BH    - The page number.
    ;===========================================================================
    rmPrintString:
            push ax
            push ds
            push si
            mov ah, 0x0E
        .printCharacter:
            lodsb
            or al, al
            jz .done
            int 0x10
            jmp .printCharacter
        .done:
            pop si
            pop ds
            pop ax
            ret

    ;===========================================================================
    ; Description: Prints an 8-bit unsigned integer to the screen.
    ;---------------------------------------------------------------------------
    ; Parameters:-
    ;     AL - The 8-bit unsigned integer.
    ;     BL - The foreground colour.
    ;     BH - The page number.
    ;     CL - The base to print in (2 to 16).
    ;     CH - The minimum number of digits to print (use 0 for no padding).
    ;===========================================================================
    rmPrintUInt8:
        push eax
        movzx eax, al
        jmp rmPrintUInt32.initialise
            
    ;===========================================================================
    ; Description: Prints a 16-bit unsigned integer to the screen.
    ;---------------------------------------------------------------------------
    ; Parameters:-
    ;     AX - The 16-bit unsigned integer.
    ;     BL - The foreground colour.
    ;     BH - The page number.
    ;     CL - The base to print in (2 to 16).
    ;     CH - The minimum number of digits to print (use 0 for no padding).
    ;===========================================================================
    rmPrintUInt16:
        push eax
        movzx eax, ax
        jmp rmPrintUInt32.initialise
            
    ;===========================================================================
    ; Description: Prints a 32-bit unsigned integer to the screen.
    ;---------------------------------------------------------------------------
    ; Parameters:-
    ;     EAX - The 32-bit unsigned integer.
    ;     BL  - The foreground colour.
    ;     BH  - The page number.
    ;     CL  - The base to print in (2 to 16).
    ;     CH  - The minimum number of digits to print (use 0 for no padding).
    ;===========================================================================
    rmPrintUInt32:
            push eax
        .initialise:
            push ebx
            push cx
            push edx
            mov [cs:.tempBX], bx
            movzx ebx, cl
            xor cl, cl
            jmp .pushDigit
        .tempBX: dw 0
        .pushDigit:
            xor edx, edx
            div ebx
            push dx
            inc cl
            or eax, eax
            jnz .pushDigit
            mov al, '0'
            mov ah, 0x0E
            mov bx, [cs:.tempBX]
        .printPadding:
            cmp cl, ch
            jge .popDigit
            int 0x10
            dec ch
            jmp .printPadding
        .popDigit:
            pop ax
            dec cl
            and al, 0x0F
            add al, 0x30
            cmp al, 0x39
            jle .printDigit
            add al, 0x07
        .printDigit:
            mov ah, 0x0E
            int 0x10
            or cl, cl
            jnz .popDigit
            pop edx
            pop cx
            pop ebx
            pop eax
            ret
            
%endif