Create a multiboot header in ld script

[torshie]

Add the following section at the beginning your ld script.

Code: Select all

	.mboot : ALIGN(16) {
		/* Multiboot header */
		LONG(0x1BADB002); /* Magic */
		LONG(1 << 16); /* Flags */
		LONG(-((1 << 16) + 0x1BADB002)); /* Checksum */
		LONG(ADDR(.mboot));
		LONG(ADDR(.text));
		LONG(__data_end__); /* End of data section */
		LONG(__bss_end__); /* End of bss section */
		LONG(_start); /* Entry point */
	}

Have fun

[xenos]

Very nice! I guess one needs to add some arithmetics if the physical and virtual addresses of the sections differ, such as

Code: Select all

   .mboot : ALIGN(16) {
      /* Multiboot header */
      LONG(0x1BADB002); /* Magic */
      LONG(1 << 16); /* Flags */
      LONG(-((1 << 16) + 0x1BADB002)); /* Checksum */
      LONG(ADDR(.mboot) - KERNEL_OFFSET);
      LONG(ADDR(.text) - KERNEL_OFFSET);
      LONG(__data_end__ - KERNEL_OFFSET); /* End of data section */
      LONG(__bss_end__ - KERNEL_OFFSET); /* End of bss section */
      LONG(_start - KERNEL_OFFSET); /* Entry point */
   }

And of course some people may want to add some flags (module page alignment, memory info...). But anyway, I really like the idea!

[Solar]

Very slick, very clean. I love it!

[torshie]

Found a better way to specify the end address of a section
"LONG(__data_end__)" and "LONG(__bss_end__)" can be replaced with "LONG(ADDR(.data) + SIZEOF(.data))" and "LONG(ADDR(.bss) + SIZEOF(.bss))" respectively.

[blobmiester]

I must add my voice to the rabble and say, "Well Done".
I'll definitely implement this in my boot stage.