OSDev.org

Code: Select all

;************************************
; Smallest pmode vesa demo
; By Craig Bamford (Dex)
;
; Assemble with fasm 
; c:\fasm Vesa.asm Vesa.bin
;
; Use rawrite to put it on fdd
;
;************************************
org 0x7C00 

use16
;****************************
; Realmode startup code.
;****************************
start:
        xor   ax,ax
        mov   ds,ax
        mov   es,ax
        mov   ss,ax
        mov   sp,0x7C00 
;****************************
; Vesa start code.
;****************************
        mov  bx,4112h
        mov  ax,4f01h
        mov  di,Mode_Info	
        mov  cx,bx
        int  10h 
        
        mov  ax,4f02h
        int  10h
;*****************************
; Setting up, to enter pmode.
;*****************************
        cli 
        lgdt  [gdtr]
        
        mov   eax, cr0
        or    al,0x1 
        mov   cr0,eax
 
        jmp   0x10: protected
;*****************************
; Pmode. ;-)
;*****************************
use32
protected:
        mov   ax,0x8 
        mov   ds,ax
        mov   es,ax
        mov   ss,ax
        mov   esp,0x7C00
;*****************************
; Turn floppy off (if space).
;*****************************
        mov   dx,3F2h
        mov   al,0
        out   dx,al
;*****************************
; Do we have 32 BitsPerPixel.
;*****************************
        cmp   byte[ModeInfo_BitsPerPixel],32
        jne   ErrorStop 
;*****************************
; fade background screen.
;*****************************
fill_screen:
        mov   edi,[ModeInfo_PhysBasePtr]
        xor   eax,eax
        mov   ecx,640*480
        rep   stosd
;*****************************
; Plot_pixel.
;*****************************
Plot_pixel:
        mov   edi,[ModeInfo_PhysBasePtr]
        mov   eax,0x00ffffff
        mov   ecx,10
        rep   stosd
;*****************************
; ErrorStop.
;*****************************
ErrorStop:
        hlt
        jmp   $
;*************************************
; GDT. 
;*************************************
gdt:        dw    0x0000, 0x0000, 0x0000, 0x0000
sys_data:   dw    0xFFFF, 0x0000, 0x9200, 0x00CF
sys_code:   dw    0xFFFF, 0x0000, 0x9800, 0x00CF
gdt_end:

gdtr:	    dw gdt_end - gdt - 1	                                  
	    dd gdt 

;*************************************
; Make program 510 byte's + 0xaa55
;*************************************
times 510- ($-start)  db 0  
dw 0xaa55
;*************************************
; Put uninitialized data here.
;*************************************
include 'vesa.inc'

Code: Select all

;=========================================================;
; Vesa Information Block                         11/12/03 ;
;---------------------------------------------------------;
; DOS EXTREME OS V0.01                                    ;
; by Craig Bamford(Dex).                                  ;
;                                                         ;
;=========================================================;

;============================== VESA MODE INFORMATION ===========================================
Mode_Info:		
ModeInfo_ModeAttributes		rw	1
ModeInfo_WinAAttributes		rb	1
ModeInfo_WinBAttributes		rb	1
ModeInfo_WinGranularity		rw	1
ModeInfo_WinSize		rw	1
ModeInfo_WinASegment		rw	1
ModeInfo_WinBSegment		rw	1
ModeInfo_WinFuncPtr		rd	1
ModeInfo_BytesPerScanLine	rw	1
ModeInfo_XResolution		rw	1
ModeInfo_YResolution		rw	1
ModeInfo_XCharSize		rb	1
ModeInfo_YCharSize		rb	1
ModeInfo_NumberOfPlanes		rb	1
ModeInfo_BitsPerPixel		rb	1
ModeInfo_NumberOfBanks		rb	1
ModeInfo_MemoryModel		rb	1
ModeInfo_BankSize		rb	1
ModeInfo_NumberOfImagePages	rb	1
ModeInfo_Reserved_page		rb	1
ModeInfo_RedMaskSize		rb	1
ModeInfo_RedMaskPos		rb	1
ModeInfo_GreenMaskSize		rb	1
ModeInfo_GreenMaskPos		rb	1
ModeInfo_BlueMaskSize		rb	1
ModeInfo_BlueMaskPos		rb	1
ModeInfo_ReservedMaskSize	rb	1
ModeInfo_ReservedMaskPos	rb	1
ModeInfo_DirectColorModeInfo	rb	1
; VBE 2.0 extensions
ModeInfo_PhysBasePtr		rd	1
ModeInfo_OffScreenMemOffset	rd	1
ModeInfo_OffScreenMemSize	rw	1

Code: Select all

        mov   edi,[ModeInfo_PhysBasePtr]

Code: Select all

        mov   eax,0x00ffffff

Code: Select all

        mov   ecx,10

Code: Select all

        rep   stosd

Code: Select all

        mov   edi,[ModeInfo_PhysBasePtr]
        add    edi,640*4
        mov   eax,0x00ffffff
        mov   ecx,10
        rep   stosd

Code: Select all

fill_screen:
        mov   edi,[ModeInfo_PhysBasePtr]
        xor   eax,eax
        mov   ecx,640*480
        rep   stosd

Code: Select all

use16
org 0x7C00

start:
			mov ax,0
			mov es,ax
			mov bx,1000h
	
			mov ah,2
			mov al,10
			xor ch,ch
			mov cl,2
			mov dh,0
			int 13h
vesa_LFB:
			mov   ax,4F01h
			mov   cx,4112h
			int   0x10
			
			xor eax,eax
			mov eax,dword[es:di + 40]
			mov dword[LinearBaseAddr],eax
vesa_GFX:
			mov ax,4F02h
			mov bx,112h		;101h = 640x480x8 112h = 640x480x32 118h = 1024x768x32bit
			or bx, 4000h	;enable frame buffer bit 14
			int 10h
gate_A20:
			in al,0x92
			or al,2
			out 0x92,al
		
			cli

			xor ax,ax
			mov ds,ax
		
			lgdt [gdt_desc]
		
			mov eax, cr0
			or eax, 1
			mov cr0, eax

			jmp 08h:pmode
		
		
use32
pmode:
			mov ax, 10h
			mov ds, ax
			mov ss, ax
			mov es, ax
			mov gs, ax
			mov fs, ax
			mov esp,090000h
		
			mov eax,[LinearBaseAddr]
			push eax	
			
kernel32:		
		jmp 08h:1000h
			
		
gdt:

gdt_null:
			dd 0
			dd 0
gdt_code:
			dw 0FFFFh
			dw 0
			db 0
			db 10011010b
			db 11001111b
			db 0
gdt_data:
			dw 0FFFFh
			dw 0
			db 0
			db 10010010b
			db 11001111b
			db 0
gdt_end:
gdt_desc:
			dw gdt_end - gdt - 1
			dd gdt
		
LinearBaseAddr dd 0,0,0,0

times 510 - ($ - $$) db 0
db 0x55
db 0xAA

Code: Select all

Code: Select all

use32
org 0000h


start:
		nop
		nop
		;mov byte[gs:0B8000h],'+'
		;mov byte[gs:0B8001h],1Bh
		
		pop eax
		mov [LinearBaseAddr],eax
main32:		

		mov   edi,[LinearBaseAddr]
        mov   eax,0x00ffffff
        mov   ecx,640*480
        rep   stosd

		jmp main32
		
		
LinearBaseAddr dd 0,0,0,0